ALGORITMO QUE CALCULE EL SUELDO A PAGAR SEGÚN EDAD Y SEXO

Calcular el sueldo según edad y el género en pseint.

💻 Hacer un programa que calcule el costo por hora de un trabajador según su edad, si es menor a 18 años el costo por hora es de $10 de lo contrario de $15; adicionalmente si el empleado es hombre se da una bonificación de $100 por trabajar en sobre tiempos, a las mujeres no se les da sobre tiempos. Ingresar las horas que trabajo, la edad y el sexo del empleado para luego mostrar el sueldo a pagar.

Análisis del código:

En este ejercicio primero ingresamos la cantidad de horas trabajadas, luego ingresamos la edad para consultar si es mayor a 18 o no y obtener el costo por hora, luego consultamos si el empleado es hombre o mujer para incrementar el monto de bonificación; para los calculos se multiplica la cantidad de horas trabajadas por el costo por hora más la bonificación, con todo ello obtenemos el costo a pagar.

Ejemplo :
01. Primero ingresamos las horas trabajadas : horasT = 40 hrs.
02. Segundo ingresamos la edad del empleado : edad = 20
03. Tercero ingresamos el sexo [H - M] : sexo = H - Hombre
04. Ahora obtenemos el costo por hora preguntando si es menor a 18 : ¿edad < 18? = no por lo tanto el costo por hora es igual a $15 [CostoH = 15]
05. La siguiente consulta es por el sexo para obtener la bonificación : ¿sexo == "H"? en este caso, si es hombre por lo tanto tiene bonificación [Boni = 100]
06. Teniendo todos los calculos, obtenemos el sueldo a pagar : SueldoP = (costoH * horasT) + Boni.
07. Aplicando los calculos : SueldoP = (15 * 40) + 100 = 700
08. El sueldo a pagar por esa semana sería : $700.

PSeInt Estricto : DESCARGA EL CÓDIGO

Proceso programacion_work 
    // 	Calcular el sueldo a pagar según las horas trabajadas, el sexo y la edad.
    Definir horasT, edad como Entero;           // Declara las variables horas trabajadas y edad
    Definir sexo como Caracter;                 // Declara el sexo
    Definir Boni, costoH , SueldoP como Real;   // Declara bonificación, costo por hora y sueldo
    Boni <- 0;                                  // Inicializa la variable bonificación en cero
    SueldoP <- 0;                               // Inicializa la variable sueldo a pagar en cero
    Escribir Sin Saltar "HORAS TRABAJADAS : ";  // Solicita el ingreso de las horas trabajadas
    Leer horasT;                                // Guarda las horas trabajadas ingresadas
    Escribir Sin Saltar "EDAD : ";              // Solicita el ingreso de la edad
    Leer edad;                                  // Guarda la edad ingresada
    Escribir Sin Saltar "SEXO [H - M] : ";      // Solicita el ingreso del sexo H - M
    Leer sexo;                                  // Guarda el sexo ingresado
    Si (edad < 18) Entonces                     // Consulta si la edad es menor a 18
        costoH <- 10;                           // Si es correcto el costo por hora es igual a 10
    SiNo                                        // Caso contrario
        costoH <- 15;                           // El costo por hora es igual a 15
    FinSi                                       // Termina la estructura de consulta
    Si (sexo == "H") Entonces                   // Pregunta si el sexo es igual a H de hombre
        Boni <- 100;                            // Si es correcto la bonificación es igual a 100
    SiNo                                        // Caso contrario
        Boni <- 0;                              // La bonificación es igual a 0
    FinSi                                       // Fin de la consulta
    SueldoP <- (costoH * horasT) + Boni;        // Calcula el sueldo a pagar
    Escribir "";				
    Escribir "SUELDO A PAGAR : $.",SueldoP;     // Muestra el sueldo a pagar
FinProceso

PSeInt Flexible :

Algoritmo programacion_work 
    Escribir Sin Saltar "HORAS TRABAJADAS : "
    Leer horasT
    Escribir Sin Saltar "EDAD : "
    Leer edad
    Escribir Sin Saltar "SEXO [H - M] : "
    Leer sexo
    Si (edad < 18) Entonces
        costoH = 10
    SiNo
        costoH = 15
    FinSi
    SI (sexo == "H") Entonces
        Boni = 100
    SiNo
        Boni = 0
    FinSi
    SueldoP = (costoH * horasT) + Boni
    Escribir ""
    Escribir "SUELDO A PAGAR : $.",SueldoP
FinAlgoritmo