ALGORITMO QUE MUESTRE EL COLOR MAS VOTADO

Algoritmo que selecciones 3 colores en pseint.

💻 Se cuenta con N personas para hacer una prueba, la cantidad de N personas es ingresa por el usuario. A cada persona se le pide que diga cuál de estos tres colores (Rojo, Verde o Azul) es su preferido y no puede responder ninguno. Se necesita calcular e informar la cantidad de personas que eligió cada color y cuál de los colores es el más elegido.

Resuelve usando PARA.

PSeInt Estricto : DESCARGA EL CÓDIGO

VER EL CÓDIGO

Algoritmo programacion_work
    Definir i, N, r, v, a como Entero;
    Definir c, Mcolor como Caracter;
    r <- 0; 
    v <- 0; 
    a <- 0;	
    Escribir Sin Saltar "CANTIDAD DE PERSONAS : ";
    Leer N;
    Para i <- 1 Hasta N Con Paso 1 Hacer
        Escribir Sin Saltar "PERSONA Nro.",i, " ";
        c <- "";
        Mientras (c<>"ROJO" Y c<>"VERDE" Y c<>"AZUL") Hacer
            Escribir Sin Saltar "[ROJO - VERDE - AZUL] :";
            Leer c;
            c <- MAYUSCULAS(c);
        FinMientras
        SI (c == "ROJO") Entonces
            r <- r + 1;
        SiNo
            SI (c == "VERDE") Entonces
                v <- v + 1;
            SiNo
                a <- a + 1;
            FinSi
        FinSi
    FinPara
    Escribir "";
    Si (r > v y r > a) Entonces
        Mcolor <- "ROJO";
    SiNo
        Si (v > r y v > a) Entonces
            Mcolor <- "VERDE";
        SiNo
            Mcolor <- "AZUL";
        FinSi
    FinSi
    Escribir "CANTIDAD DE COLOR ROJO   : ", r;
    Escribir "CANTIDAD DE COLOR VERDE  : ", v;
    Escribir "CANTIDAD DE COLOR AZUL   : ", a;
    Escribir "EL COLOR MAS ESCOGIDO ES : ", Mcolor;
FinProceso

PSeInt Flexible :

Algoritmo programacion_work
    Escribir Sin Saltar "CANTIDAD DE PERSONAS : "
    Leer N
    Para i = 1 Hasta N Con Paso 1 Hacer
        Escribir Sin Saltar "PERSONA Nro.",i, " "
        c = ""
        Mientras (c<>"ROJO" Y c<>"VERDE" Y c<>"AZUL") Hacer
            Escribir Sin Saltar "[ROJO - VERDE - AZUL] :"
            Leer c
            c = MAYUSCULAS(c)
        FinMientras
        SI (c == "ROJO") Entonces
            r = r + 1
        SiNo
            SI (c == "VERDE") Entonces
                v = v + 1
            SiNo
                a = a + 1
            FinSi
        FinSi
    FinPara
    Escribir ""
    Si (r > v y r > a) Entonces
        Mcolor = "ROJO"
    SiNo
        Si (v > r y v > a) Entonces
            Mcolor = "VERDE"
        SiNo
            Mcolor = "AZUL"
        FinSi
    FinSi
    Escribir "CANTIDAD DE COLOR ROJO   : ", r
    Escribir "CANTIDAD DE COLOR VERDE  : ", v
    Escribir "CANTIDAD DE COLOR AZUL   : ", a
    Escribir "EL COLOR MAS ESCOGIDO ES : ", Mcolor
FinAlgoritmo

Este código es un programa escrito en el lenguaje de programación Pseint que tiene como objetivo contar la cantidad de personas que eligen uno de los tres colores (rojo, verde o azul) y determinar cuál es el color más elegido. El proceso comienza solicitando al usuario que ingrese la cantidad de personas a ser consideradas utilizando la función "Leer N".

Luego, se utiliza un bucle "Para i <- 1 Hasta N Con Paso 1" para iterar N veces, en cada iteración se le pide al usuario que ingrese un color utilizando la función "Leer c" y se valida que el color ingresado sea uno de los tres colores permitidos (rojo, verde o azul) utilizando un bucle "Mientras (c<>"ROJO" Y c<>"VERDE" Y c<>"AZUL")".

Una vez que se ha ingresado un color válido, se utiliza una serie de estructuras de control "SI" para contar la cantidad de personas que han elegido cada color y determinar cuál es el color más elegido.

Finalmente, se muestra en pantalla la cantidad de personas que han elegido cada color y el color más elegido.